jmail组件下载

石家庄网站建设

JMail是一款非常成熟的邮件收发组件，它的免费版本已经基本能完成我们的需要，况且windows 2003虚拟主机默认都支持JMail组件，对于ASP程序员，JMail组必不可少的工具。

最新更新JMAIL组件下载地址: http://www.ajiang.net/products/download/coms/jmail44_free.zip

JMail(4.3)中文手册

　　w3 JMail 是 Dimac 公司（www.dimac.net）推出的ASP发信组件，可以在ASP、VC、VB、Delphi等开发工具中调用。和其他发信组件相比，它具有支持HTML、多收件人、抄送、暗送等特点。4.0以上版本除了具备以上特点外，还有以下优点：
　　
　　1、支持需要发信认证的SMTP服务器（现在多数免费邮箱都需要SMTP发信认证）。
　　2、当服务器支持SMTP发信时，JMail可以将信件加入SMTP发信队列（速度很快）。
　　3、支持在HTML邮件中嵌入附件中的图片。
　　4、支持POP3收信（不支持WEB收发信的信箱也可以自己搞定了）。
　　5、支持PGP加密邮件。
　　6、支持邮件合并（群发邮件，每封信可以不同。）
　　
　　下载：
　　英文原版：http://www.ajiang.net/luntan/w3jmail4.pdf
　　翻译后的：http://www.ajiang.net/luntan/w3jmail4_cn.pdf
　　V3.7中文：http://www.ajiang.net/luntan/w3JMial37.pdf

下面是一个Jmail发邮件的例子代码：

如果您在自己的机器上试，请下载Jmail.dll，下载解压后，双击Setup.bat 即可完成安装！

<%
On error resume next
Dim JMail, contentId
Set JMail = Server.CreateObject("JMail.Message")
JMail.Charset = "gb2312" ' 邮件字符集，默认为"US-ASCII"
' JMail.ISOEncodeHeaders = False ' 是否进行ISO编码，默认为True

' 发送者信息（可用变量方式赋值）
JMail.From = "Cavien@cavien.com" ' 发送者地址
JMail.FromName = "Cavien" ' 发送者姓名
JMail.Subject = "邮件主题" ' 邮件主题

' 身份验证
JMail.MailServerUserName = "myusername" ' 身份验证的用户名
JMail.MailServerPassword = "mypassword" ' 身份验证的密码

' 设置优先级，范围从1到5，越大的优先级越高，3为普通
JMail.Priority = 3

JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")

' 加入一个收件人【变量email：收件人地址】可以同一语句重复加入多个
JMail.AddRecipient("someone@somehost.com")

' 加入附件【变量filename：附件文件的绝对地址，确保用户IUSR_机器名有访问的权限】
' 【参数设置是(True)否(False)为Inline方式】
'contentId = JMail.AddAttachment (Server.MapPath("jmail.asp"), True)

' 邮件主体（HTML(注意信件内链接附件的方式)）
JMail.HTMLBody = "<html><head><META content=zh-cn http-equiv=Content-Language><meta http-equiv=""Content-Type"" content=""text/html; charset=gb2312""><style type=text/css>A:link { FONT-SIZE: 9pt; TEXT-DECORATION: none; color: #000000}A:visited {FONT-SIZE: 9pt; TEXT-DECORATION: none; color: #666666}A:hover {COLOR: #ff6600; FONT-SIZE: 9pt; TEXT-DECORATION: underline}BODY {FONT-SIZE: 9pt} --></style></head><body><font color=red>邮件正文</font><br><font color=green>邮件正文</font><br><b>邮件正文</b></body></html>"

' 邮件主体（文本部分）
JMail.Body = "我们的邮件采用了HTML格式，但是您的邮件查看软件可能不支持。。。邮件正文,邮件正文,邮件正文"

' 发送【调用格式：objJMail.Send([username:password@]SMTPServerAddress[:Port])】
JMail.Send("smtp.163.com")

' 关闭并清除对象
JMail.Close()
Set JMail = Nothing

if err.number<>0 then
response.write "发送发送失败！"
else
response.write "邮件发送成功！"
end if
%>

jmail组件下载

相关内容